#!/usr/bin/awk -f

# Use \t as output separator
BEGIN {
  OFS       = "\t"
  f_graph   = gensub(".mean" , ".graph.csv"     , "g" , ARGV[1])
  f_tab_all = gensub(".mean" , ".table_all.csv" , "g" , ARGV[1])
  f_tab_tvi = gensub(".mean" , ".table_tvi.csv" , "g" , ARGV[1])
}

# $1: domain
# (#bellman, total_time):
#   VI=($2, $3), LRTDP=($4, $5), ILAO=($6, $7),
#   TVI=($13, $14), eTVI=($20, $21), eiTVI=($27, $28)
# ($11, $12): (#SCC, |SCC_max|)
# (tarjan, reorder, scc_solve):
#   TVI: ($8, $9, $10)
#   eTVI: ($15, $16, $17)
#   eiTVI: ($22, $23, $24)

{
  split($3  , VI    , "±")
  split($5  , LRTDP , "±")
  split($7  , ILAO  , "±")
  split($14 , TVI   , "±")
  split($21 , eTVI  , "±")
  split($28 , eiTVI , "±")

  # Headers
  if (FNR == 1)
    print $1, $3, "±", $5, "±", $7, "±", $14, "±", $21, "±", $28, "±" > f_graph
  else
    print $1, VI[1], VI[2], LRTDP[1], LRTDP[2], ILAO[1], ILAO[2],
             TVI[1], TVI[2], eTVI[1], eTVI[2], eiTVI[1], eiTVI[2] > f_graph

  print $1, $11, $12, $2, $3, $4, $5, $6, $7, $13, $14, $20, $21, $27, $28 > f_tab_all
  print $1, $11, $12, $8, $9, $10, $13, $15, $16, $17, $20, $22, $23, $24, $27 > f_tab_tvi
}

END {
  close(f_graph)
  close(f_tab_all)
  close(f_tab_tvi)
}
